You can not select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
613 lines
22 KiB
613 lines
22 KiB
add_custom_target(resources)
|
|
add_custom_target(test-resources)
|
|
|
|
set(STORM_3RDPARTY_SOURCE_DIR ${PROJECT_SOURCE_DIR}/resources/3rdparty)
|
|
set(STORM_3RDPARTY_BINARY_DIR ${PROJECT_BINARY_DIR}/resources/3rdparty)
|
|
|
|
if (STORM_PYTHON)
|
|
find_package(PythonInterp 3 REQUIRED QUIET)
|
|
find_package(PythonLibs 3 REQUIRED QUIET)
|
|
|
|
message(STATUS "Python executable: ${PYTHON_EXECUTABLE}")
|
|
message(STATUS "Python include: ${PYTHON_INCLUDE_DIRS}")
|
|
message(STATUS "Python include: ${PYTHON_LIBRARIES}")
|
|
endif()
|
|
|
|
#############################################################
|
|
##
|
|
## l3pp
|
|
##
|
|
#############################################################
|
|
|
|
# Do not take a branch, needs internet connection.
|
|
ExternalProject_Add(
|
|
l3pp
|
|
GIT_REPOSITORY https://github.com/hbruintjes/l3pp.git
|
|
GIT_TAG e4f8d7fe6c328849aff34d2dfd6fd592c14070d5
|
|
SOURCE_DIR ${STORM_3RDPARTY_SOURCE_DIR}/l3pp
|
|
UPDATE_COMMAND ""
|
|
CONFIGURE_COMMAND ""
|
|
BUILD_COMMAND ""
|
|
INSTALL_COMMAND ""
|
|
LOG_INSTALL ON
|
|
)
|
|
ExternalProject_Get_Property(l3pp source_dir)
|
|
set(l3pp_INCLUDE "${source_dir}/")
|
|
include_directories(${l3pp_INCLUDE})
|
|
add_dependencies(resources l3pp)
|
|
|
|
#############################################################
|
|
##
|
|
## gmm
|
|
##
|
|
#############################################################
|
|
|
|
# Add the shipped version of GMM to the include pathes
|
|
set(GMMXX_INCLUDE_DIR "${PROJECT_SOURCE_DIR}/resources/3rdparty/gmm-5.0/include")
|
|
include_directories(${GMMXX_INCLUDE_DIR})
|
|
|
|
#############################################################
|
|
##
|
|
## Eigen
|
|
##
|
|
#############################################################
|
|
|
|
# Add the shipped version of Eigen to the include pathes
|
|
set(EIGEN_INCLUDE_DIR "${PROJECT_SOURCE_DIR}/resources/3rdparty/eigen-3.3-beta1")
|
|
include_directories(${EIGEN_INCLUDE_DIR})
|
|
|
|
|
|
#############################################################
|
|
##
|
|
## Boost
|
|
##
|
|
#############################################################
|
|
|
|
# Boost Option variables
|
|
set(Boost_USE_STATIC_LIBS ${USE_BOOST_STATIC_LIBRARIES})
|
|
set(Boost_USE_MULTITHREADED ON)
|
|
set(Boost_USE_STATIC_RUNTIME OFF)
|
|
|
|
find_package(Boost 1.61.0 QUIET REQUIRED COMPONENTS filesystem system)
|
|
if (NOT Boost_FOUND)
|
|
if (Boost_VERSION)
|
|
message(FATAL_ERROR "The required Boost version is 1.61.0 or newer, however, only ${Boost_VERSION} was found.")
|
|
else ()
|
|
message(FATAL_ERROR "Boost was not found.")
|
|
endif ()
|
|
endif ()
|
|
if ((NOT Boost_LIBRARY_DIRS) OR ("${Boost_LIBRARY_DIRS}" STREQUAL ""))
|
|
set(Boost_LIBRARY_DIRS "${Boost_INCLUDE_DIRS}/stage/lib")
|
|
endif ()
|
|
link_directories(${Boost_LIBRARY_DIRS})
|
|
|
|
include_directories(${Boost_INCLUDE_DIRS})
|
|
list(APPEND STORM_LINK_LIBRARIES ${Boost_LIBRARIES})
|
|
message(STATUS "Storm - Using boost ${Boost_VERSION} (library version ${Boost_LIB_VERSION}).")
|
|
# set the information for the config header
|
|
set(STORM_BOOST_INCLUDE_DIR "${Boost_INCLUDE_DIRS}")
|
|
|
|
#############################################################
|
|
##
|
|
## ExprTk
|
|
##
|
|
#############################################################
|
|
|
|
# Use the shipped version of ExprTK
|
|
message (STATUS "Storm - Including ExprTk.")
|
|
include_directories("${PROJECT_SOURCE_DIR}/resources/3rdparty/exprtk")
|
|
|
|
#############################################################
|
|
##
|
|
## Sparsepp
|
|
##
|
|
#############################################################
|
|
|
|
# Use the shipped version of Sparsepp
|
|
message (STATUS "Storm - Including Sparsepp.")
|
|
include_directories("${PROJECT_SOURCE_DIR}/resources/3rdparty/sparsepp")
|
|
|
|
# Add sparsepp.h to the headers that are copied to the include directory in thebuild directory.
|
|
add_custom_command(
|
|
OUTPUT ${CMAKE_BINARY_DIR}/include/resources/3rdparty/sparsepp/sparsepp.h
|
|
COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/include/resources/3rdparty/sparsepp
|
|
COMMAND ${CMAKE_COMMAND} -E copy ${PROJECT_SOURCE_DIR}/resources/3rdparty/sparsepp/sparsepp.h ${CMAKE_BINARY_DIR}/include/resources/3rdparty/sparsepp/sparsepp.h
|
|
DEPENDS ${PROJECT_SOURCE_DIR}/resources/3rdparty/sparsepp/sparsepp.h
|
|
)
|
|
list(APPEND STORM_RESOURCES_HEADERS "${CMAKE_BINARY_DIR}/include/resources/3rdparty/sparsepp/sparsepp.h")
|
|
|
|
#############################################################
|
|
##
|
|
## ModernJSON
|
|
##
|
|
#############################################################
|
|
|
|
#use the shipped version of modernjson
|
|
message (STATUS "Storm - Including ModernJSON.")
|
|
include_directories("${PROJECT_SOURCE_DIR}/resources/3rdparty/modernjson/src/")
|
|
|
|
#############################################################
|
|
##
|
|
## Z3 (optional)
|
|
##
|
|
#############################################################
|
|
|
|
find_package(Z3 QUIET)
|
|
|
|
# Z3 Defines
|
|
set(STORM_HAVE_Z3 ${Z3_FOUND})
|
|
|
|
if(Z3_FOUND)
|
|
message (STATUS "Storm - Linking with Z3.")
|
|
include_directories(${Z3_INCLUDE_DIRS})
|
|
list(APPEND STORM_LINK_LIBRARIES ${Z3_LIBRARIES})
|
|
endif(Z3_FOUND)
|
|
|
|
#############################################################
|
|
##
|
|
## glpk
|
|
##
|
|
#############################################################
|
|
|
|
include(${STORM_3RDPARTY_SOURCE_DIR}/include_glpk.cmake)
|
|
|
|
#############################################################
|
|
##
|
|
## Gurobi (optional)
|
|
##
|
|
#############################################################
|
|
|
|
if (STORM_USE_GUROBI)
|
|
find_package(Gurobi QUIET REQUIRED)
|
|
set(STORM_HAVE_GUROBI ${GUROBI_FOUND})
|
|
if (GUROBI_FOUND)
|
|
message (STATUS "Storm - Linking with Gurobi.")
|
|
include_directories(${GUROBI_INCLUDE_DIRS})
|
|
list(APPEND STORM_LINK_LIBRARIES ${GUROBI_LIBRARY})
|
|
#link_directories("${GUROBI_ROOT}/lib")
|
|
endif()
|
|
else()
|
|
set(STORM_HAVE_GUROBI OFF)
|
|
endif()
|
|
|
|
#############################################################
|
|
##
|
|
## CUDD
|
|
##
|
|
#############################################################
|
|
include(${STORM_3RDPARTY_SOURCE_DIR}/include_cudd.cmake)
|
|
|
|
#############################################################
|
|
##
|
|
## cpptemplate
|
|
##
|
|
#############################################################
|
|
include(${STORM_3RDPARTY_SOURCE_DIR}/include_cpptemplate.cmake)
|
|
|
|
#############################################################
|
|
##
|
|
## CLN
|
|
##
|
|
#############################################################
|
|
|
|
find_package(CLN QUIET)
|
|
|
|
if(CLN_FOUND)
|
|
set(STORM_HAVE_CLN ON)
|
|
message(STATUS "Storm - Linking with CLN ${CLN_VERSION_STRING}.")
|
|
include_directories("${CLN_INCLUDE_DIR}")
|
|
list(APPEND STORM_LINK_LIBRARIES ${CLN_LIBRARIES})
|
|
else()
|
|
set(STORM_HAVE_CLN OFF)
|
|
if(NOT GMP_FOUND)
|
|
message(FATAL_ERROR "Storm - Neither CLN nor GMP found.")
|
|
endif()
|
|
endif()
|
|
|
|
#############################################################
|
|
##
|
|
## carl
|
|
##
|
|
#############################################################
|
|
|
|
set(STORM_HAVE_CARL OFF)
|
|
if(USE_CARL)
|
|
find_package(carl QUIET)
|
|
if(carl_FOUND)
|
|
set(STORM_HAVE_CARL ON)
|
|
message(STATUS "Storm - Use system version of carl.")
|
|
message(STATUS "Storm - Linking with carl ${carl_VERSION_STRING}.")
|
|
include_directories("${carl_INCLUDE_DIR}")
|
|
list(APPEND STORM_LINK_LIBRARIES ${carl_LIBRARIES})
|
|
else()
|
|
message(STATUS "Storm - Using shipped version of carl.")
|
|
set(CARL_BUILD_COMMAND make lib_carl)
|
|
if(STORM_PYTHON)
|
|
set(CARL_BUILD_COMMAND ${CARL_BUILD_COMMAND} PythonBindingsDevelop)
|
|
endif()
|
|
ExternalProject_Add(
|
|
carl
|
|
GIT_REPOSITORY https://github.com/smtrat/carl
|
|
GIT_TAG master
|
|
INSTALL_DIR ${STORM_3RDPARTY_BINARY_DIR}/carl
|
|
SOURCE_DIR ${STORM_3RDPARTY_SOURCE_DIR}/carl
|
|
CMAKE_ARGS -DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER} -DBOOST_INCLUDEDIR=${Boost_INCLUDE_DIRS} -DBOOST_LIBRARYDIR=${Boost_LIBRARY_DIRS} -DBoost_NO_SYSTEM_PATHS=1 -DEXPORT_TO_CMAKE=0 -DUSE_CLN_NUMBERS=1 -DCMAKE_SKIP_INSTALL_ALL_DEPENDENCY=1 -DCMAKE_INSTALL_PREFIX:PATH=${STORM_3RDPARTY_BINARY_DIR}/carl -DBINDINGS_PYTHON=${STORM_PYTHON} -DPYTHON_LIBRARY=${PYTHON_LIBRARY} -DPYTHON_INCLUDE_DIR=${PYTHON_INCLUDE_DIR} -DPYTHON_EXECUTABLE=${PYTHON_EXECUTABLE}
|
|
BUILD_IN_SOURCE 0
|
|
BUILD_COMMAND ${CARL_BUILD_COMMAND}
|
|
INSTALL_COMMAND ""
|
|
LOG_UPDATE ON
|
|
LOG_CONFIGURE ON
|
|
LOG_BUILD ON
|
|
BUILD_BYPRODUCTS ${STORM_3RDPARTY_BINARY_DIR}/carl/lib/libcarl${DYNAMIC_EXT}
|
|
)
|
|
|
|
add_dependencies(resources carl)
|
|
set(carl_INCLUDE_DIR "${STORM_3RDPARTY_BINARY_DIR}/carl/include")
|
|
include_directories("${carl_INCLUDE_DIR}")
|
|
list(APPEND STORM_LINK_LIBRARIES ${STORM_3RDPARTY_BINARY_DIR}/carl/lib/libcarl${DYNAMIC_EXT})
|
|
set(STORM_HAVE_CARL ON)
|
|
endif()
|
|
endif()
|
|
set(STORM_CARL_INCLUDE_DIR "${carl_INCLUDE_DIR}")
|
|
|
|
|
|
#############################################################
|
|
##
|
|
## SMT-RAT
|
|
##
|
|
#############################################################
|
|
|
|
set(STORM_HAVE_SMTRAT OFF)
|
|
if(USE_SMTRAT)
|
|
find_package(smtrat QUIET REQUIRED)
|
|
if(smtrat_FOUND)
|
|
set(STORM_HAVE_SMTRAT ON)
|
|
message(STATUS "Storm - Linking with smtrat.")
|
|
include_directories("${smtrat_INCLUDE_DIR}")
|
|
list(APPEND STORM_LINK_LIBRARIES ${smtrat_LIBRARIES})
|
|
else()
|
|
message(FATAL_ERROR "StoRM - SMT-RAT was requested but not found")
|
|
endif()
|
|
endif()
|
|
|
|
|
|
#############################################################
|
|
##
|
|
## HyPro
|
|
##
|
|
#############################################################
|
|
|
|
set(STORM_HAVE_HYPRO OFF)
|
|
if(USE_HYPRO)
|
|
find_package(hypro QUIET REQUIRED)
|
|
if(hypro_FOUND)
|
|
set(STORM_HAVE_HYPRO ON)
|
|
message(STATUS "Storm - Linking with hypro ${hypro_VERSION_STRING}.")
|
|
include_directories("${hypro_INCLUDE_DIR}")
|
|
link_directories( /Users/tim/hypro/build )
|
|
list(APPEND STORM_LINK_LIBRARIES ${hypro_LIBRARIES})
|
|
else()
|
|
message(FATAL_ERROR "StoRM - HyPro was requested but not found")
|
|
endif()
|
|
endif()
|
|
|
|
|
|
|
|
#############################################################
|
|
##
|
|
## GiNaC
|
|
##
|
|
#############################################################
|
|
|
|
find_package(GiNaC QUIET)
|
|
|
|
if(GINAC_FOUND)
|
|
set(STORM_HAVE_GINAC ON)
|
|
message(STATUS "Storm - Linking with GiNaC ${GINAC_VERSION_STRING}.")
|
|
# Right now only link with GiNaC for carl
|
|
#include_directories("${GINAC_INCLUDE_DIR}")
|
|
list(APPEND STORM_LINK_LIBRARIES ${GINAC_LIBRARIES})
|
|
else()
|
|
set(STORM_HAVE_GINAC OFF)
|
|
#TODO: Check if CARL actually requires the use of GiNaC
|
|
endif()
|
|
|
|
|
|
#############################################################
|
|
##
|
|
## gmp
|
|
##
|
|
#############################################################
|
|
|
|
# GMP is optional (unless MathSAT is used, see below)
|
|
find_package(GMP QUIET)
|
|
|
|
#############################################################
|
|
##
|
|
## MathSAT (optional)
|
|
##
|
|
#############################################################
|
|
|
|
if ("${MSAT_ROOT}" STREQUAL "")
|
|
set(ENABLE_MSAT OFF)
|
|
else()
|
|
set(ENABLE_MSAT ON)
|
|
endif()
|
|
|
|
# MathSAT Defines
|
|
set(STORM_HAVE_MSAT ${ENABLE_MSAT})
|
|
if (ENABLE_MSAT)
|
|
message (STATUS "Storm - Linking with MathSAT.")
|
|
link_directories("${MSAT_ROOT}/lib")
|
|
include_directories("${MSAT_ROOT}/include")
|
|
list(APPEND STORM_LINK_LIBRARIES "mathsat")
|
|
if(GMP_FOUND)
|
|
include_directories("${GMP_INCLUDE_DIR}")
|
|
list(APPEND STORM_LINK_LIBRARIES "gmp")
|
|
elseif(MPIR_FOUND)
|
|
include_directories("${GMP_INCLUDE_DIR}")
|
|
list(APPEND STORM_LINK_LIBRARIES "mpir" "mpirxx")
|
|
else(GMP_FOUND)
|
|
message(FATAL_ERROR "GMP is required for MathSAT, but was not found!")
|
|
endif(GMP_FOUND)
|
|
endif(ENABLE_MSAT)
|
|
|
|
#############################################################
|
|
##
|
|
## Xerces
|
|
##
|
|
#############################################################
|
|
|
|
include(${STORM_3RDPARTY_SOURCE_DIR}/include_xerces.cmake)
|
|
|
|
#############################################################
|
|
##
|
|
## Sylvan
|
|
##
|
|
#############################################################
|
|
|
|
ExternalProject_Add(
|
|
sylvan
|
|
DOWNLOAD_COMMAND ""
|
|
PREFIX "sylvan"
|
|
SOURCE_DIR ${STORM_3RDPARTY_SOURCE_DIR}/sylvan
|
|
CMAKE_ARGS -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER} -DSYLVAN_BUILD_TEST=Off -DSYLVAN_BUILD_EXAMPLES=Off -DCMAKE_BUILD_TYPE=Release -DCMAKE_POSITION_INDEPENDENT_CODE=ON
|
|
BINARY_DIR ${PROJECT_BINARY_DIR}/sylvan
|
|
BUILD_IN_SOURCE 0
|
|
INSTALL_COMMAND ""
|
|
INSTALL_DIR ${STORM_3RDPARTY_BINARY_DIR}/sylvan
|
|
LOG_CONFIGURE ON
|
|
LOG_BUILD ON
|
|
BUILD_BYPRODUCTS ${PROJECT_BINARY_DIR}/sylvan/src/libsylvan${STATIC_EXT}
|
|
)
|
|
ExternalProject_Get_Property(sylvan source_dir)
|
|
ExternalProject_Get_Property(sylvan binary_dir)
|
|
set(Sylvan_INCLUDE_DIR "${source_dir}/src")
|
|
set(Sylvan_LIBRARY "${binary_dir}/src/libsylvan${STATIC_EXT}")
|
|
message(STATUS "Storm - Using shipped version of sylvan.")
|
|
message(STATUS "Storm - Linking with sylvan.")
|
|
include_directories("${Sylvan_INCLUDE_DIR}")
|
|
list(APPEND STORM_LINK_LIBRARIES ${Sylvan_LIBRARY})
|
|
add_dependencies(resources sylvan)
|
|
|
|
if(${OPERATING_SYSTEM} MATCHES "Linux")
|
|
find_package(Hwloc QUIET REQUIRED)
|
|
if(HWLOC_FOUND)
|
|
message(STATUS "Storm - Linking with hwloc ${HWLOC_VERSION}.")
|
|
list(APPEND STORM_LINK_LIBRARIES ${HWLOC_LIBRARIES})
|
|
else()
|
|
message(FATAL_ERROR "HWLOC is required but was not found.")
|
|
endif()
|
|
endif()
|
|
|
|
#############################################################
|
|
##
|
|
## Google Test gtest
|
|
##
|
|
#############################################################
|
|
set(GOOGLETEST_LIB_DIR ${STORM_3RDPARTY_BINARY_DIR}/gtest-1.7.0)
|
|
ExternalProject_Add(
|
|
googletest
|
|
#For downloads (may be useful later!)
|
|
#SVN_REPOSITORY http://googletest.googlecode.com/svn/trunk/
|
|
#TIMEOUT 10
|
|
DOWNLOAD_COMMAND ""
|
|
SOURCE_DIR "${STORM_3RDPARTY_SOURCE_DIR}/gtest-1.7.0"
|
|
# Force the same output paths for debug and release builds so that
|
|
# we know in which place the binaries end up when using the Xcode generator
|
|
CMAKE_ARGS -Dgtest_force_shared_crt=ON -DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER} -DCMAKE_ARCHIVE_OUTPUT_DIRECTORY_DEBUG:PATH=${GOOGLETEST_LIB_DIR} -DCMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELEASE:PATH=${GOOGLETEST_LIB_DIR}
|
|
# Disable install step
|
|
INSTALL_COMMAND ""
|
|
BINARY_DIR ${GOOGLETEST_LIB_DIR}
|
|
INSTALL_DIR ${GOOGLETEST_LIB_DIR}
|
|
# Wrap download, configure and build steps in a script to log output
|
|
LOG_CONFIGURE ON
|
|
LOG_BUILD ON
|
|
BUILD_BYPRODUCTS ${GOOGLETEST_LIB_DIR}/libgtest${STATIC_EXT} ${GOOGLETEST_LIB_DIR}/libgtest_main${STATIC_EXT}
|
|
)
|
|
|
|
# Specify include dir
|
|
ExternalProject_Get_Property(googletest source_dir)
|
|
set(GTEST_INCLUDE_DIR ${source_dir}/include)
|
|
# Specify MainTest's link libraries
|
|
ExternalProject_Get_Property(googletest binary_dir)
|
|
set(GTEST_LIBRARIES ${binary_dir}/libgtest${STATIC_EXT} ${binary_dir}/libgtest_main${STATIC_EXT})
|
|
|
|
add_dependencies(test-resources googletest)
|
|
list(APPEND STORM_TEST_LINK_LIBRARIES ${GTEST_LIBRARIES})
|
|
|
|
#############################################################
|
|
##
|
|
## Intel Threading Building Blocks (optional)
|
|
##
|
|
#############################################################
|
|
|
|
set(STORM_HAVE_INTELTBB OFF)
|
|
if (STORM_USE_INTELTBB)
|
|
find_package(TBB QUIET REQUIRED)
|
|
|
|
if (TBB_FOUND)
|
|
message(STATUS "Storm - Found Intel TBB with interface version ${TBB_INTERFACE_VERSION}.")
|
|
message(STATUS "Storm - Linking with Intel TBB in ${TBB_LIBRARY_DIRS}.")
|
|
set(STORM_HAVE_INTELTBB ON)
|
|
link_directories(${TBB_LIBRARY_DIRS})
|
|
include_directories(${TBB_INCLUDE_DIRS})
|
|
list(APPEND STORM_LINK_LIBRARIES tbb tbbmalloc)
|
|
else(TBB_FOUND)
|
|
message(FATAL_ERROR "Storm - TBB was requested, but not found.")
|
|
endif(TBB_FOUND)
|
|
endif(STORM_USE_INTELTBB)
|
|
|
|
#############################################################
|
|
##
|
|
## Threads
|
|
##
|
|
#############################################################
|
|
|
|
find_package(Threads QUIET REQUIRED)
|
|
if (NOT Threads_FOUND)
|
|
message(FATAL_ERROR "Storm - Threads was requested, but not found.")
|
|
endif()
|
|
include_directories(${THREADS_INCLUDE_DIRS})
|
|
list(APPEND STORM_LINK_LIBRARIES ${CMAKE_THREAD_LIBS_INIT})
|
|
if (STORM_USE_COTIRE)
|
|
target_link_libraries(storm_unity ${CMAKE_THREAD_LIBS_INIT})
|
|
endif(STORM_USE_COTIRE)
|
|
|
|
#############################################################
|
|
##
|
|
## CUDA Library generation
|
|
##
|
|
#############################################################
|
|
|
|
|
|
if ("${CUDA_ROOT}" STREQUAL "")
|
|
set(ENABLE_CUDA OFF)
|
|
else()
|
|
set(ENABLE_CUDA ON)
|
|
endif()
|
|
|
|
# CUDA Defines
|
|
if (ENABLE_CUDA)
|
|
set(STORM_CPP_CUDA_DEF "define")
|
|
else()
|
|
set(STORM_CPP_CUDA_DEF "undef")
|
|
endif()
|
|
|
|
|
|
# CUDA Defines
|
|
set(STORM_CPP_CUDAFORSTORM_DEF "undef")
|
|
|
|
|
|
if(ENABLE_CUDA)
|
|
# Test for type alignment
|
|
try_run(STORM_CUDA_RUN_RESULT_TYPEALIGNMENT STORM_CUDA_COMPILE_RESULT_TYPEALIGNMENT
|
|
${PROJECT_BINARY_DIR} "${PROJECT_SOURCE_DIR}/cuda/CMakeAlignmentCheck.cpp"
|
|
COMPILE_OUTPUT_VARIABLE OUTPUT_TEST_VAR
|
|
)
|
|
if(NOT STORM_CUDA_COMPILE_RESULT_TYPEALIGNMENT)
|
|
message(FATAL_ERROR "Storm (CudaPlugin) - Could not test type alignment, there was an Error while compiling the file ${PROJECT_SOURCE_DIR}/cuda/CMakeAlignmentCheck.cpp: ${OUTPUT_TEST_VAR}")
|
|
elseif(STORM_CUDA_RUN_RESULT_TYPEALIGNMENT EQUAL 0)
|
|
message(STATUS "StoRM (CudaPlugin) - Result of Type Alignment Check: OK.")
|
|
else()
|
|
message(FATAL_ERROR "Storm (CudaPlugin) - Result of Type Alignment Check: FAILED (Code ${STORM_CUDA_RUN_RESULT_TYPEALIGNMENT})")
|
|
endif()
|
|
|
|
# Test for Float 64bit Alignment
|
|
try_run(STORM_CUDA_RUN_RESULT_FLOATALIGNMENT STORM_CUDA_COMPILE_RESULT_FLOATALIGNMENT
|
|
${PROJECT_BINARY_DIR} "${PROJECT_SOURCE_DIR}/cuda/CMakeFloatAlignmentCheck.cpp"
|
|
COMPILE_OUTPUT_VARIABLE OUTPUT_TEST_VAR
|
|
)
|
|
if(NOT STORM_CUDA_COMPILE_RESULT_FLOATALIGNMENT)
|
|
message(FATAL_ERROR "Storm (CudaPlugin) - Could not test float type alignment, there was an Error while compiling the file ${PROJECT_SOURCE_DIR}/cuda/CMakeFloatAlignmentCheck.cpp: ${OUTPUT_TEST_VAR}")
|
|
elseif(STORM_CUDA_RUN_RESULT_FLOATALIGNMENT EQUAL 2)
|
|
message(STATUS "Storm (CudaPlugin) - Result of Float Type Alignment Check: 64bit alignment active.")
|
|
set(STORM_CUDAPLUGIN_FLOAT_64BIT_ALIGN_DEF "define")
|
|
elseif(STORM_CUDA_RUN_RESULT_FLOATALIGNMENT EQUAL 3)
|
|
message(STATUS "Storm (CudaPlugin) - Result of Float Type Alignment Check: 64bit alignment disabled.")
|
|
set(STORM_CUDAPLUGIN_FLOAT_64BIT_ALIGN_DEF "undef")
|
|
else()
|
|
message(FATAL_ERROR "Storm (CudaPlugin) - Result of Float Type Alignment Check: FAILED (Code ${STORM_CUDA_RUN_RESULT_FLOATALIGNMENT})")
|
|
endif()
|
|
#
|
|
# Make a version file containing the current version from git.
|
|
#
|
|
include(GetGitRevisionDescription)
|
|
git_describe_checkout(STORM_GIT_VERSION_STRING)
|
|
# Parse the git Tag into variables
|
|
string(REGEX REPLACE "^([0-9]+)\\..*" "\\1" STORM_CUDAPLUGIN_VERSION_MAJOR "${STORM_GIT_VERSION_STRING}")
|
|
string(REGEX REPLACE "^[0-9]+\\.([0-9]+).*" "\\1" STORM_CUDAPLUGIN_VERSION_MINOR "${STORM_GIT_VERSION_STRING}")
|
|
string(REGEX REPLACE "^[0-9]+\\.[0-9]+\\.([0-9]+).*" "\\1" STORM_CUDAPLUGIN_VERSION_PATCH "${STORM_GIT_VERSION_STRING}")
|
|
string(REGEX REPLACE "^[0-9]+\\.[0-9]+\\.[0-9]+\\-([0-9]+)\\-.*" "\\1" STORM_CUDAPLUGIN_VERSION_COMMITS_AHEAD "${STORM_GIT_VERSION_STRING}")
|
|
string(REGEX REPLACE "^[0-9]+\\.[0-9]+\\.[0-9]+\\-[0-9]+\\-([a-z0-9]+).*" "\\1" STORM_CUDAPLUGIN_VERSION_HASH "${STORM_GIT_VERSION_STRING}")
|
|
string(REGEX REPLACE "^[0-9]+\\.[0-9]+\\.[0-9]+\\-[0-9]+\\-[a-z0-9]+\\-(.*)" "\\1" STORM_CUDAPLUGIN_VERSION_APPENDIX "${STORM_GIT_VERSION_STRING}")
|
|
if ("${STORM_CUDAPLUGIN_VERSION_APPENDIX}" MATCHES "^.*dirty.*$")
|
|
set(STORM_CUDAPLUGIN_VERSION_DIRTY 1)
|
|
else()
|
|
set(STORM_CUDAPLUGIN_VERSION_DIRTY 0)
|
|
endif()
|
|
message(STATUS "Storm (CudaPlugin) - Version information: ${STORM_CUDAPLUGIN_VERSION_MAJOR}.${STORM_CUDAPLUGIN_VERSION_MINOR}.${STORM_CUDAPLUGIN_VERSION_PATCH} (${STORM_CUDAPLUGIN_VERSION_COMMITS_AHEAD} commits ahead of Tag) build from ${STORM_CUDAPLUGIN_VERSION_HASH} (Dirty: ${STORM_CUDAPLUGIN_VERSION_DIRTY})")
|
|
|
|
|
|
# Configure a header file to pass some of the CMake settings to the source code
|
|
configure_file (
|
|
"${PROJECT_SOURCE_DIR}/cuda/storm-cudaplugin-config.h.in"
|
|
"${PROJECT_BINARY_DIR}/include/storm-cudaplugin-config.h"
|
|
)
|
|
|
|
#create library
|
|
find_package(CUDA REQUIRED)
|
|
set(CUSP_INCLUDE_DIRS "${PROJECT_SOURCE_DIR}/resources/3rdparty/cusplibrary")
|
|
find_package(Cusp REQUIRED)
|
|
find_package(Thrust REQUIRED)
|
|
|
|
set(STORM_CUDA_LIB_NAME "storm-cuda")
|
|
|
|
file(GLOB_RECURSE STORM_CUDA_KERNEL_FILES ${PROJECT_SOURCE_DIR}/cuda/kernels/*.cu)
|
|
file(GLOB_RECURSE STORM_CUDA_HEADER_FILES ${PROJECT_SOURCE_DIR}/cuda/kernels/*.h)
|
|
|
|
source_group(kernels FILES ${STORM_CUDA_KERNEL_FILES} ${STORM_CUDA_HEADER_FILES})
|
|
include_directories(${PROJECT_SOURCE_DIR}/cuda/kernels/)
|
|
|
|
#set(CUDA_PROPAGATE_HOST_FLAGS OFF)
|
|
set(CUDA_NVCC_FLAGS "-arch=sm_30")
|
|
|
|
#############################################################
|
|
##
|
|
## CUSP
|
|
##
|
|
#############################################################
|
|
if(CUSP_FOUND)
|
|
include_directories(${CUSP_INCLUDE_DIR})
|
|
cuda_include_directories(${CUSP_INCLUDE_DIR})
|
|
message(STATUS "Storm (CudaPlugin) - Found CUSP Version ${CUSP_VERSION} in location ${CUSP_INCLUDE_DIR}.")
|
|
else()
|
|
message(FATAL_ERROR "Storm (CudaPlugin) - Could not find CUSP.")
|
|
endif()
|
|
|
|
#############################################################
|
|
##
|
|
## Thrust
|
|
##
|
|
#############################################################
|
|
if(THRUST_FOUND)
|
|
include_directories(${THRUST_INCLUDE_DIR})
|
|
cuda_include_directories(${THRUST_INCLUDE_DIR})
|
|
message(STATUS "Storm (CudaPlugin) - Found Thrust Version ${THRUST_VERSION} in location ${THRUST_INCLUDE_DIR}.")
|
|
else()
|
|
message(FATAL_ERROR "Storm (CudaPlugin) - Could not find Thrust. Check your CUDA installation.")
|
|
endif()
|
|
|
|
include_directories(${CUDA_INCLUDE_DIRS})
|
|
include_directories(${ADDITIONAL_INCLUDE_DIRS})
|
|
|
|
cuda_add_library(${STORM_CUDA_LIB_NAME}
|
|
${STORM_CUDA_KERNEL_FILES} ${STORM_CUDA_HEADER_FILES}
|
|
)
|
|
|
|
message (STATUS "Storm - Linking with CUDA.")
|
|
list(APPEND STORM_LINK_LIBRARIES ${STORM_CUDA_LIB_NAME})
|
|
include_directories("${PROJECT_SOURCE_DIR}/cuda/kernels/")
|
|
endif()
|
|
|
|
add_custom_target(copy_resources_headers DEPENDS ${CMAKE_BINARY_DIR}/include/resources/3rdparty/sparsepp/sparsepp.h ${CMAKE_BINARY_DIR}/include/resources/3rdparty/sparsepp/sparsepp.h)
|